//----------------------------------------------------------------------------------------------
//【画圆】 
// 由八段curveTo组成
function drawCircle(mc, r) {
	var scale = Math.cos(Math.PI/8);
	mc.moveTo(r, 0);
	for (var i = Math.PI/4; i<=Math.PI*2; i += Math.PI/4) {
		var cx = Math.cos(i-Math.PI/8)*r/scale;
		var cy = Math.sin(i-Math.PI/8)*r/scale;
		var ax = Math.cos(i)*r;
		var ay = Math.sin(i)*r;
		mc.curveTo(cx, cy, ax, ay);
	}
}

createEmptyMovieClip("circle_mc", 0);
circle_mc._x = 200;
circle_mc._y = 200;
circle_mc.lineStyle(2, 0xff0000, 100);
drawCircle(circle_mc, 100);


//----------------------------------------------------------------------------------------------
//【画虚线】 
function drawDashedLine(mc:MovieClip, x1:Number, y1:Number, x2:Number, y2:Number) {
	var dash = 5+Math.floor(Math.random()*5);
	var step = dash+3;
	var angle = Math.atan2(y2-y1, x2-x1);
	var dashx = dash*Math.cos(angle);
	var dashy = dash*Math.sin(angle);
	var stepx = step*Math.cos(angle);
	var stepy = step*Math.sin(angle);
	var _length = Math.sqrt(Math.pow(x2-x1, 2)+Math.pow(y2-y1, 2));
	with (mc) {
		lineStyle(0, 0xff0000, 100);
		for (var i = step, px = x1, py = y1; i<=_length; i += step) {
			moveTo(px, py);
			lineTo(px+dashx, py+dashy);
			px += stepx;
			py += stepy;
		}
		moveTo(px, py);
		lineTo(x2, y2);
	}
}
drawDashedLine(this, 22, 44, 66, 88);


//----------------------------------------------------------------------------------------------
//【画直线】 
// x1, y1: 起点坐标		x2, y2: 终点坐标		t是粗细 0<=t<=255
MovieClip.prototype.drawLine = function(x1, y1, x2, y2, t) {
	this.lineStyle(t);
	this.moveTo(x1, y1);
	this.lineTo(x2, y2);
};
this.createEmptyMovieClip("line_mc", 0);
line_mc.drawLine(10, 10, 100, 100, 2);



//----------------------------------------------------------------------------------------------
//【画螺旋线】 
// w、h为宽和高	f控制线的长短，用弧度表示 
MovieClip.prototype.drawHelix = function(w, h, f) {
	for (var i = 0; i<f; i += 0.05) {
		this.lineTo(x=Math.sin(i)*i*w, y=Math.cos(i)*i*h);
		this.lineStyle(1);
	}
};
// 以(100,100)为中心画螺旋线 
this.createEmptyMovieClip("helix_mc", 0);
with (helix_mc) {
	drawHelix(5, 5, 13);
	_x = _y = 100;
}



//----------------------------------------------------------------------------------------------
//【正多边形】n为边数，正五边形(50, 50, 5)，椭圆(25, 50, 100)，圆(50, 50, 100)
MovieClip.prototype.drawPolygon = function(w, h, n) {
	f = 2*Math.PI;
	for (var i = 0; i<=f/n*(n+1); i += f/n) {
		this.lineTo(x=Math.sin(i)*w, y=Math.cos(i)*h);
		this.lineStyle(1);
	}
};
// 画一正五边形 
this.createEmptyMovieClip("pentagon_mc", 0);
with (pentagon_mc) {
	drawPolygon(50, 50, 5);
	_x = _y = 100;
}



//----------------------------------------------------------------------------------------------
//【抛物线】
MovieClip.prototype.drawParabola = function(l, r, k) {
	for (var i = -l; i<=r; i += 1) {
		this.lineTo(x=i, y=k*i*i);
		this.lineStyle(1);
	}
};
//usage
this.createEmptyMovieClip("parabola_mc", 100);
with (parabola_mc) {
	drawParabola(50, 50, 0.05);
	_x = _y=100;	// 顶点坐标 
}



//----------------------------------------------------------------------------------------------
//【正弦线·余弦类】 
MovieClip.prototype.drawSin = function(n, k) {
	for (var i = 0; i<=90*n; i += 1) {
		this.lineTo(x=i, y=k*Math.sin(i*Math.PI/180));
		this.lineStyle(1);
	}
};
this.createEmptyMovieClip("sin_mc", 0);
with (sin_mc) {
	drawSin(4, 50);
	_x = _y=100;	// 顶点坐标 
}



//----------------------------------------------------------------------------------------------
//【wave】 
MovieClip.prototype.drawWave = function(w, h) {
	for (var i = 0; i<=6.3; i += 0.01) {
		this.lineTo(x=w/Math.cos(i), y=h*Math.sin(i)/Math.cos(i));
		this.lineStyle(1);
	}
};
_root.createEmptyMovieClip("wave_mc", 0);
with (wave_mc) {
	drawWave(100, 100);
	_x = _y = 200;		// 顶点坐标 	
}