// ------------------------------------------------------------------------------------------------------------------
// skipCache.as 跳过缓存
/*
**************************************************************
* Developed by R.Arul Kumaran [arul@shockwave-india.com]     *
* for more code keep visiting [www.shockwave-india.com/blog] *
**************************************************************
version 1.1 Last updated on 9, Jan 2004
*/
/*
| Useful when you don't want your server files to be cached by both server and browser
|
|   getSkipCacheString() - Return a blank string("") when the swf is running as a local file and
|                          returns a random string like "?CacheBuster=0.0308893630281091&timestamp=1073037565155"
|                          when the swf is from a web server
|
*/
_global.getSkipCacheString = function() {
        if (getSkipCacheString.isLocalPlayback) {
                return "";
        }
        dStr = "&timestamp="+new Date().getTime();
        return "?CacheBuster="+Math.random()+dStr;
};
getSkipCacheString.isLocalPlayback = _url.indexOf("file") == 0;
/*
//sample usage
#include "skipCache.as"
my_xml = new XML();
my_xml.onData = function(dta) {
trace(dta);
};
my_xml.load("myfile.xml"+getSkipCacheString());


// ------------------------------------------------------------------------------------------------------------------
// toString.as 打印obj的所有内容
/*
************************************************************
Developed by R.Arul Kumaran [arul@shockwave-india.com]     *
for more code keep visiting [www.shockwave-india.com/blog] *
************************************************************
version 3.6 Last updated on 12 Oct, 2003
Thanks to Ampre[ampreind@hotmail.com] for the initial improvements to my Object.toAS() code
*/
/*
|   Object.toString() - Create a actionscript string for the given object with out circular references
|                   	Useful for tracing objects for local and remote debugging
|
|	ActionScript(Object, 'name_of_the_variable') - gets complete reusable actionscript of the Object including circular reference
*/
_global.ActionScript = function(obj, name) {
        ActionScript._Dump = [];
        var str = name+' = '+obj.toString(name)+ActionScript.lineBrake+ActionScript._Dump.join(ActionScript.lineBrake);
        delete ActionScript._Dump;
        return str;
};
ActionScript.lineBrake = "\n";
ActionScript.spacer = "\t";
ActionScript.makeString = function(t, name, spacer) {
        var y = typeof (t);
        switch (y) {
                case "object" :
                return (ActionScript.getString(t, name, spacer, t instanceof Array ? 1 : 0));
                case "function" :
                return (ActionScript.getString(t, name, spacer, 2));
                case "boolean" :
                case "number" :
                return (t);
                case "string" :
                return (t.toString());
                case "movieclip" :
                var m = t._target.split('/').join('.');
                return (m.length>1 ? '_root'+m : '_root');
                default :
                return (y == '' ? t : y);
        }
};
ActionScript.getString = function(t, name, spacer, mode) {
        var s = new String();
        if(spacer==undefined)spacer='';
        t.__name__ = name;
        t.IsCircularReference = true;
        ASSetPropFlags(t, "IsCircularReference,__name__", 1);
        for (var i in t) {
                var special = false;
                var l = i.length;
                while (l--) {
                        var c = i.charAt(l);
                        if ("abcdefghijklmnopqrstuvwxyz0123456789_".indexOf(c.toLowerCase())<0) {
                                special = true;
                                break;
                        }
                }
                if (!t[i].IsCircularReference) {
                        if (special) {
                                ActionScript._Dump.push(t.__name__+'[\"'+i+'\"] = '+ActionScript.makeString(t[i], name+'.'+i, spacer+ActionScript.spacer)+';');
                        } else {
                                switch (mode) {
                                        case 0 :
                                        //Objects
                                        var rS = ActionScript.makeString(t[i], name+'.'+i, spacer+ActionScript.spacer);
                                        if (rS != '' && rS != undefined) {
                                                s += ActionScript.lineBrake+spacer+ActionScript.spacer+i+':'+rS+", ";
                                        }
                                        break;
                                        default :
                                        //Object definition
                                        if (isNaN(i)) {
                                                var rS = ActionScript.makeString(t[i], name+'.'+i, '');
                                                if (rS != '' && rS != undefined) {
                                                        ActionScript._Dump.push(t.__name__+'.'+i+' = '+rS+';');
                                                }
                                        }
                                }
                        }
                } else {
                        if (isNaN(i)) {
                                ActionScript._Dump.push(special ? t.__name__+'[\"'+i+'\"] = '+t[i].__name__ : t.__name__+'.'+i+' = '+t[i].__name__+';');
                        }
                }
        }
        switch (mode) {
                case 1 :
                //Array
                for (var i = 0; i<t.length; i++) {
                        if (!t[i].IsCircularReference) {
                                var rS = ActionScript.makeString(t[i], name, spacer+ActionScript.spacer);
                                if (rS != '' && rS != undefined) {
                                        s += ActionScript.lineBrake+spacer+ActionScript.spacer+rS+", ";
                                }
                        } else {
                                ActionScript._Dump.push(t.__name__+'['+i+'] = '+t[i].__name__+';');
                        }
                }
                if (s.length) {
                        s = "["+substring(s, 1, s.length-2)+ActionScript.lineBrake+spacer+"]";
                } else {
                        s = "[]";
                }
                break;
                case 2 :
                //Function
                ActionScript._Dump.push(t.__name__+" = function(){\n}");
                s = "";
                //s = "function(){\n"+spacer+"}";
                break;
                default :
                //Generic Objects
                if (s.length) {
                        s = "{"+substring(s, 1, s.length-2)+ActionScript.lineBrake+spacer+"}";
                } else {
                        s = "{}";
                }
        }
        delete t.IsCircularReference;
        delete t.__name__;
        return s;
};
Object.prototype.toString = function(name, spacer) {
        return ActionScript.getString(this, name, spacer, 0);
};
Array.prototype.toString = function(name, spacer) {
        return ActionScript.getString(this, name, spacer, 1);
};
Function.prototype.toString = function(name, spacer) {
        return ActionScript.getString(this, name, spacer, 2);
};
String.prototype.toString = function() {
        return "\""+this.split("'").join("\\'").split('\"').join('\\\"').split('\r').join('\\r').split(ActionScript.lineBrake).join('\\n')+"\"";
};
ASSetPropFlags(Function.prototype, "toString", 1);
ASSetPropFlags(String.prototype, "toString", 1);



//Example:-
//#include "toString.as"
var a = {num:20, str:"Escaped \"Q\"uote's and \rline \nbrakes", arr:['str', 30], obj:{aa:33, bol:true}};
a.self = a;
a.blank = undefined;
a.func = function() {trace("me");};
a.func.arr = [1, 2];
a.func.ref = a;
a.obj.parent = a.obj;
a.obj.parents = a;
a.arr.push(a);
a.arr.push(a.arr);
a.arr.ref = a.arr;
a.arr.func = function() {};
trace(a);
trace(ActionScript(a, 'a'));


// ------------------------------------------------------------------------------------------------------------------
// colorUtils.as 颜色值格式转换
/*
************************************************************
Developed by R.Arul Kumaran [arul@shockwave-india.com]     *
for more code keep visiting [www.shockwave-india.com/blog] *
************************************************************
*/
//Set of funtions for handling color values in different format

/*-----------------------------------------------------
//getHexStr: returns a string representing the
//HEX value for the specified R,G,B values
*/
_global.getHexStr = function(r, g, b) {
        return twoDigit(r.toString(16))+twoDigit(g.toString(16))+twoDigit(b.toString(16));
};
/*
//Usage:-
trace(getHexStr(255,255,255));
//traces "ffffff"
*/
/*-----------------------------------------------------
//getHex: returns the HEX value for the
//specified R,G,B values
*/
_global.getHex = function(r, g, b) {
        return r << 16 | g << 8 | b;
};
/*
//Usage:-
trace(getHex(255,255,255));
//traces 16777215
*/
/*-----------------------------------------------------
//HexToRGB: returns the RGB (as Object) for the
//specified HEX value
*/
_global.HexToRGB = function(HEX) {
        return {r:HEX >> 16, g:(HEX >> 8) & 0xff, b:HEX & 0xff};
};
/*
//Usage:-
trace(HexToRGB(0x0c0c0c).r);
//traces 12 (the red value)
*/
/*-----------------------------------------------------
//twoDigit: adds "0" in front if the string is only
// one digit also useful for converting date time strings
*/
function twoDigit(str) {
        return str.length == 1 ? "0"+str : str;
}
/*
//Example:-
var myDate = new Date();
var timeStr = twoDigit(myDate.getHours())+twoDigit(myDate.getMinutes());
trace(timeStr);
//traces "01:09"
*/

// ------------------------------------------------------------------------------------------------------------------
// Object-copyProperties.as 对象属性拷贝
/*
************************************************************
Developed by R.Arul Kumaran [arul@shockwave-india.com]     *
for more code keep visiting [www.shockwave-india.com/blog] *
************************************************************
*/
/*
|   Object.copyProperties(toObj, PropertyStr, exclude?)
|
|   toObj:          Object to which properties to be copied
|
|   propertyStr:    list of properties to be included or excluded in
|                   "#property1#property2#property3#" format
|
|   exclude:        boolean specifies whether to exclude or include the properties
|                   mentioned in the propertyStr
*/
Object.prototype.copyProperties = function(toObj, propertyStr, exclude) {
        if (this instanceof Array) {
                for (var i = 0; i<this.length; i++) {
                        if (typeof (this[i]) == "object") {
                                toObj[i] = this[i] instanceof Array ? new Array() : new Object();
                                this[i].copyProperties(toObj[i], propertyStr, exclude);
                        } else {
                                toObj[i] = this[i];
                        }
                }
        } else {
                for (var i in this) {
                        var index = propertyStr.indexOf("#"+i+"#");
                        if ((exclude && index == -1) || (!exclude && index != -1)) {
                                if (typeof (this[i]) == "object") {
                                        toObj[i] = this[i] instanceof Array ? [] : {};
                                        this[i].copyProperties(toObj[i], propertyStr, exclude);
                                } else {
                                        toObj[i] = this[i];
                                }
                        }
                }
        }
}
ASSetPropFlags(Object.prototype, ["copyProperties"], 1);


//Example:-
// creating a generic object with some properties we need
myObj = {align:"left", color:0xFF0000, name:"arul", gender:"male"};
//creating a textformat object
myTextFormat = new TextFormat();
//method 1
myObj.copyProperties(myTextFormat, "#align#color#")
//myTextFormat now has align and color properties
//method 2
myObj.copyProperties(myTextFormat, "#name#gender#",true)
//myTextFormat now has all the properties copied except name and gender