package com.oxylusflash.book 
{
	import caurina.transitions.Tweener;
	import flash.display.Sprite;
	import flash.events.MouseEvent;
	
	public class CloseSearchButton extends FadeInOutItem
	{
		// The two states of the button.
		public var normalState:Sprite;
		public var overState:Sprite;
		
		public function CloseSearchButton() 
		{
			this.alpha = 0;			
			this.buttonMode = true;
			this.mouseChildren = false;
			
			normalState.filters = [Global.SHADOW];
			normalState.cacheAsBitmap = true;
			
			overState.alpha = 0;
			overState.filters = [Global.GLOW];	
			overState.cacheAsBitmap = true;
			
			_state = FadeInOutItem.INVISIBLE;
			
			this.addEventListener(MouseEvent.ROLL_OVER, rollOverHandler, false, 0, true);
			this.addEventListener(MouseEvent.ROLL_OUT, rollOutHandler, false, 0, true);
		}		
		
		/**
		 * Event handlers.
		 * @param	e
		 */
		private function rollOverHandler(e:MouseEvent):void 
		{
			Tweener.addTween(overState, { alpha: 1, base: Global.baseTween } );
		}
		
		private function rollOutHandler(e:MouseEvent):void 
		{
			Tweener.addTween(overState, { alpha: 0, base: Global.baseTween } );
		}
		
		/**
		 * Overrides.
		 */
		override public function get alpha():Number { return super.alpha; }		
		override public function set alpha(value:Number):void 
		{
			super.alpha = value;
			this.mouseEnabled = value == 1;
		}
	}
}