package {
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.ui.Mouse;
    import flash.ui.MouseCursor;
     
    public class MultiSpring extends Sprite {
         
        private var ball:Ball;
        private var handles:Array;
        private var spring:Number=0.3;
        private var friction:Number=0.8;
        private var numHandles:Number=5;
         
        public function MultiSpring() {
            init();
        }
         
        private function init():void {
            ball=new Ball(20);
            addChild(ball);
            handles = new Array();
             
            //创建控制(点)小球
            for (var i:uint = 0; i < numHandles; i++) {
                var handle:Ball=new Ball(10,0x0000ff);
                handle.x=Math.random()*stage.stageWidth;
                handle.y=Math.random()*stage.stageHeight;
                handle.addEventListener(MouseEvent.MOUSE_DOWN, MouseDownHandler);
                addChild(handle);
                handles.push(handle);
                handle.addEventListener(MouseEvent.MOUSE_OUT,MouseOutHandler);
                handle.addEventListener(MouseEvent.MOUSE_OVER,MouseOverHandler);
            }
            addEventListener(Event.ENTER_FRAME, EnterFrameHandler);
            addEventListener(MouseEvent.MOUSE_UP, MouseUpHandler);      
             
        }
         
         
         
        function MouseOutHandler(e:MouseEvent):void{
            Mouse.cursor = MouseCursor.AUTO;
        }
         
        function MouseOverHandler(e:MouseEvent):void{
            Mouse.cursor = MouseCursor.HAND;
        }
         
        private function EnterFrameHandler(event:Event):void {
             
            //将各控制点的位置做为目标位置，叠加弹性运动
            for (var i:uint = 0; i < numHandles; i++) {
                var handle:Ball=handles[i] as Ball;
                var dx:Number=handle.x-ball.x;
                var dy:Number=handle.y-ball.y;
                ball.vx+=dx*spring;
                ball.vy+=dy*spring;
            }
             
            ball.vx*=friction;
            ball.vy*=friction;
            ball.x+=ball.vx;
            ball.y+=ball.vy;
            graphics.clear();
            graphics.lineStyle(1);
            for (i = 0; i < numHandles; i++) {
                graphics.moveTo(ball.x, ball.y);
                graphics.lineTo(handles[i].x, handles[i].y);
            }
        }
         
        private function MouseDownHandler(e:MouseEvent):void {
            e.target.startDrag();
        }
         
        private function MouseUpHandler(event:MouseEvent):void {
            stopDrag();
        }
    }
}