/*
* 
* @class		AdsXMLModel
* @version		1.1
* @authur		Azure
* @website		http://www.riacn.com
*
*/
import mx.events.EventDispatcher;
class AdsXMLModel extends XML {
	//
	// Property
	private var adurl:Array;
	private var adname:Array;
	private var adlink:Array;
	public var addEventListener:Function;
	public var removeEventListener:Function;
	private var dispatchEvent:Function;
	private static var _mixin1 = EventDispatcher.initialize(AdsXMLModel.prototype);
	// Constructor
	public function AdsXMLModel() {
		adurl = new Array();
		adname = new Array();
		adlink = new Array();
		ignoreWhite = true;
	}
	//
	// Event Handler
	private function onLoad():Void {
		var adsXML:Array = this.firstChild.childNodes;
		var itemNum:Number = adsXML.length;
		for (var i = 0; i<itemNum; i++) {
			adurl.push(adsXML[i].attributes.adurl);
			adname.push(adsXML[i].attributes.adname);
			adlink.push(adsXML[i].attributes.adlink);
		}
		this.dispatchEvent({type:"onAdsListLoaded", target:this});
	}
	//
	// Public Method
	public function getXmlLength():Number {
		return adurl.length;
	}
	public function getAdSwfUrl(i:Number):String {
		return adurl[i];
	}
	public function getAdName(i:Number):String {
		return adname[i];
	}
	public function getAdLink(i:Number):String {
		return adlink[i];
	}
	public function getAdType(i:Number):Boolean {
		var extName:String = adurl[i].toLowerCase().substr(-3, 3);
		var isSwf:Boolean;
		if (extName == "swf") {
			isSwf = true;
		} else if (extName == "jpg") {
			isSwf = false;
		}
		return isSwf;
	}
}