class Water {
	
	
	
	/*************************************************************************
	
		OPTIONAL CONSTRUCTOR PARAMETERS
	
		sq  :  sets the amount of influence points referenced in 
	      	   simulation - default is 5.
	
		r_  :  sets the number of lines the surface is divided into
	      	   - default is 20.
	
	*************************************************************************/
	
	
	private var body:Array;
	private var clip:MovieClip, dc:MovieClip;
	
	
	private var x:Number, y:Number, w:Number;
	
	
	private var resolution:Number; 
	private var simQuality:Number;
	
	private static var dampening:Number  = .95;
	private static var viscosity:Number  =  50;
	
	
	
	public function Water(x_:Number, y_:Number, w_:Number, c_:MovieClip, sq:Number, r_:Number) {
		
		
		body = [];
		
		
		clip = c_;
		dc = clip.createEmptyMovieClip("dc", 1);
		
		
		x=x_, y=y_, w=w_; 
		
		
		setQuality(sq, r_);
		buildBodyOfWater();
		
		
		
	}
	
	
	
	
	
	
	
	
	
	
	
		
		
		
		
		
		
	private function buildBodyOfWater() {
		
		
		for( var i=-1; ++i<=resolution; ) {  body.push( {x:x+w/resolution*i, y:y, vy:0, oy:y} );  }
		setControls(this);
		
		
	}
	
	
	
	
	
	
	
	
	
	
	
	
	
	
	private function addSplash(n:Number, force:Number) {
		
		body[n].vy += force;
		
		var base:Number = Number(n);
		var diff:Number = force/simQuality;
		
		for( var i=0; ++i<simQuality; ) {
			
			force-=diff;
			
			body[base-i].vy+=force;
			body[base+i].vy+=force;
			
		}
		
	}
		
	
	
	
	
	
	
	
	
	
	
	private function routine() {  update();  render();  }
	
	
	
	
	
	
	
	
	
	
	
	
	private function update() {
		
		
		for( var i=-1; ++i<body.length; ) { 
		
	
			body[i].vy*=dampening;
			
			
			var yp:Number = body[i].y;
			var influence:Number = body[i].oy - yp;
			
			
			for( var n=0; ++n<=simQuality; ) {
				
				
				influence += body[i-n] != undefined ? (body[i-n].y-yp)/(n+1): 0; 
				influence += body[i+n] != undefined ? (body[i+n].y-yp)/(n+1): 0; 
				
				
			}
			
		
			body[i].vy += influence/viscosity;
			body[i].y  += body[i].vy; 
			
		
		}
		
		
	}
	
	
	
	
	
	
	
	
	
	private function render() {
		
		var w = this;
		var c = body[0];
		
		with(dc) {
			
		
			clear();
			beginFill(0x333333,90);
			moveTo(c.x, c.y);
			
	
			for( var i=0; ++i<w.body.length; ) {  lineTo(w.body[i].x, w.body[i].y);  }
		
		
			lineTo(w.x+w.w,	Stage.height);
			lineTo(w.x,   	Stage.height);
			lineTo(w.x, 	w.body[0].y);
			
			
			endFill();
			
			
		
		}
		
		
	}
	
	
	
	
	
	
	
	
	
	
	
	private function setQuality(q:Number, r:Number) {
		
		
		resolution = r != undefined ? r: 20;
		simQuality = q != undefined ? q: 5;
		
		
	}
	
	
	
	
	
	
	
	
	
	
	
	private function setControls(arg:Water) {
		
		
		
		
		
		clip.onEnterFrame=function () {  arg.routine();  }
		
		
		
		
		
		clip.onMouseDown=function() { 
		
			
			var bx:Array  = arg.body;
			var tx:Number = this._xmouse;
			var ty:Number = this._ymouse;
			var dx:Number = arg.w/arg.resolution;
			
			
			var offset:Number = 3;
			
			
			for(var i in bx) {
		
				if( Math.abs(bx[i].x - tx) < dx ) {
					
					arg.addSplash(Number(i), (ty-bx[i].y)/(viscosity/offset));
					break;
					
				}
				
			}
					
					
		}
		
		
		
	}
	
		
	
	
	
	
}