/*
20070313
Powered by Sunday
E-mail:happyclub@163.com
*/
var wNum:Number = 8;
//地图宽度
var hNum:Number = 8;
//地图高度
var selNum:Number = 7;
//地图中最多包含几种不同的图
var tileW:Number = 30;
//方块的宽度
var tileH:Number = 30;
//方块的高度
var myMap:Array = [];
//地图数组
var score:Number = 0;
//分数
var chickArray:Array = [];
//点击存放方块信息数组
var totalClearTileArray:Array = [];
//存放符合条件要消除的方块信息数组
var wID:Number;
//方块横ID
var hID:Number;
//方块纵ID
var once:Boolean = false;
//初始化方块是否交换一次
var success:Boolean = false;
//是否成功
var chick:Boolean = true;
//是否接收用户点击
var tempS:Boolean = false;
//控制交换次数
_root.createEmptyMovieClip("tempMC", _root.getNextHighestDepth());
//---------------------------INIT--------------------------------------------
initArray(wNum, hNum, selNum);
initTie(wNum, hNum);
//showArray();显示数组
function initArray(W, H, sel) {
	for (var i:Number = 0; i<H; i++) {
		myMap[i] = [];
		for (var j:Number = 0; j<W; j++) {
			myMap[i][j] = createRandom(sel);
			myMap[i][j-2] != undefined || myMap[i-2][j] != undefined ? checkArray(i, j, sel) : null;
		}
	}
	return myMap;
}
function createRandom(sel) {
	var tempRandomNum:Number;
	tempRandomNum = random(sel)+1;
	return tempRandomNum;
}
function checkArray(a, b, sel) {
	while (myMap[a][b] == myMap[a][b-1] && myMap[a][b] == myMap[a][b-2] || (myMap[a-1][b] == myMap[a][b] && myMap[a][b] == myMap[a-2][b])) {
		myMap[a][b] = createRandom(sel);
		checkArray(a, b, sel);
	}
}
//--------------------------------INIT ARRAY--------------------------------
function initTie(a, b) {
	for (var i = 1; i<=a; i++) {
		for (var j = 1; j<=b; j++) {
			DuplicateTile(_root, tileW*j, tileH*i, i, j);
		}
	}
}
function DuplicateTile(path:Object, tX:Number, tY:Number, a, b) {
	a = a-1;
	b = b-1;
	var myDepth = _root.getNextHighestDepth();
	myTile = path.attachMovie("tile", "myTile"+a+"_"+b, myDepth);
	myTile.gotoAndStop(myMap[a][b]);
	myTile.wID = b;
	myTile.hID = a;
	myTile._x = tX;
	myTile._y = tY;
	var myTempThis = this;
	myTile.onPress = function() {
		if (chick == true) {
			_root.wID = this.wID;
			_root.hID = this.hID;
		}
	};
	myTile.onRelease = function() {
		if (chick == true) {
			chickArray.push(hID, wID);
			if (chickArray.length == 4) {
				if (chickArray[0] == chickArray[2] && chickArray[1] == chickArray[3]) {
					chickArray.splice(2, 2);
				} else if (chickArray[0] != chickArray[2] && chickArray[1] != chickArray[3]) {
					chickArray.splice(0, 2);
					trace(chickArray);
				} else {
					startGame();
				}
			}
		}
	};
	myTile.useHandCursor = false;
}
//-------------加载方块到舞台--初始化方块
/*
以上为初始化部分
*/
function startGame() {
	tempS = false;
	if ((chickArray[0] == chickArray[2] && chickArray[1] == (chickArray[3]+1)) || (chickArray[0] == chickArray[2] && chickArray[1] == (chickArray[3]-1))) {
		trace("横交换");
		changeMap();
		checkMap(true, chickArray[0]);
		checkMap(false, chickArray[1]);
		checkMap(false, chickArray[3]);
		if (totalClearTileArray.length != 0) {
			once = true;
		} else {
			totalClearTileArray = [];
			changeMap();
			once = false;
		}
		moveTile(_root["myTile"+chickArray[0]+"_"+chickArray[1]], _root["myTile"+chickArray[2]+"_"+chickArray[3]]);
	}
	if ((chickArray[1] == chickArray[3] && chickArray[0] == (chickArray[2]+1)) || (chickArray[1] == chickArray[3] && chickArray[0] == (chickArray[2]-1))) {
		trace("纵交换");
		changeMap();
		checkMap(true, chickArray[0]);
		checkMap(true, chickArray[2]);
		checkMap(false, chickArray[1]);
		if (totalClearTileArray.length != 0) {
			once = true;
		} else {
			totalClearTileArray = [];
			changeMap();
			once = false;
		}
		moveTile(_root["myTile"+chickArray[0]+"_"+chickArray[1]], _root["myTile"+chickArray[2]+"_"+chickArray[3]]);
	}
	chickArray = [];
}
//---------开始游戏
function checkMap(way:Boolean, startNum:Number) {
	var tempPassSwitch:Number = 0;
	var tempClearTileArray:Array = [];
	startNum = Number(startNum);
	way != true ? (tempA=1, tempB=0, tempI=startNum) : (tempA=0, tempB=1);
	for (var i = 0; i<8; i++) {
		way != true ? startNum=i : tempI=i;
		if (myMap[startNum][tempI] == myMap[startNum+tempA][tempI+tempB]) {
			tempClearTileArray.push(startNum, tempI);
			tempPassSwitch++;
		} else if (tempPassSwitch>=2) {
			tempClearTileArray.push(startNum, tempI);
			tempPassSwitch = 0;
			for (var j = 0; j<tempClearTileArray.length; j++) {
				var temp = tempClearTileArray[j];
				totalClearTileArray.push(temp);
			}
			tempOrder++;
			tempClearTileArray = [];
		} else {
			//没有达到消除条件
			tempClearTileArray = [];
			tempPassSwitch = 0;
		}
	}
	if (totalClearTileArray.length != 0) {
		for (var i = 0; i<totalClearTileArray.length; i += 2) {
			for (var j = i+2; j<totalClearTileArray.length; j++) {
				if (String(totalClearTileArray[i])+String(totalClearTileArray[i+1]) == String(totalClearTileArray[j])+String(totalClearTileArray[j+1])) {
					totalClearTileArray.splice(i, 2);
					continue;
				}
			}
		}
	}
	trace("totalClearTileArray   :"+totalClearTileArray);
	return totalClearTileArray.length != 0 ? true : false;
}
//--------------检查地图
function moveTile(mc1, mc2) {
	var a:Number = 0.6;
	var dx:Number;
	var dy:Number;
	var tempx1:Number = mc1._x;
	var tempx2:Number = mc2._x;
	var tempy1:Number = mc1._y;
	var tempy2:Number = mc2._y;
	onEnterFrame = function () {
		dx = tempx2-mc1._x;
		mc1._x += dx*a;
		dx = tempx1-mc2._x;
		mc2._x += dx*a;
		dy = tempy2-mc1._y;
		mc1._y += dy*a;
		dy = tempy1-mc2._y;
		mc2._y += dy*a;
		if ((Math.abs(dy) == 0 && Math.abs(dx)<0.5) || (Math.abs(dy)<0.5 && Math.abs(dx) == 0)) {
			chick = tempS == true ? true : false;
			dy = 0;
			dx = 0;
			mc1._x = tempx2;
			mc1._y = tempy2;
			mc2._x = tempx1;
			mc2._y = tempy1;
			if (once == true && tempS == false) {
				changeNum(mc1, mc2);
				changePlace(mc1, mc2);
				totalClearTileArray.length != 0 ? (chick=false, scal(totalClearTileArray)) : null;
			}
			delete this.onEnterFrame;
			if (once == false && tempS == false) {
				trace("未消除");
				once = true;
				tempS = true;
				moveTile(mc1, mc2);
			}
		}
	};
}
//--------------交换方块
function changePlace(a, b) {
	a._x = a._x ^ b._x;
	b._x = b._x ^ a._x;
	a._x = a._x ^ b._x;
	a._y = a._y ^ b._y;
	b._y = b._y ^ a._y;
	a._y = a._y ^ b._y;
}
//--------------交换方块位置
function changeNum(mc1, mc2) {
	var tempFrame:Number = mc1._currentframe;
	mc1.gotoAndStop(mc2._currentframe);
	mc2.gotoAndStop(tempFrame);
}
//----------交换方块显示
function changeMap() {
	myMap[chickArray[0]][chickArray[1]] = myMap[chickArray[0]][chickArray[1]] ^ myMap[chickArray[2]][chickArray[3]];
	myMap[chickArray[2]][chickArray[3]] = myMap[chickArray[2]][chickArray[3]] ^ myMap[chickArray[0]][chickArray[1]];
	myMap[chickArray[0]][chickArray[1]] = myMap[chickArray[0]][chickArray[1]] ^ myMap[chickArray[2]][chickArray[3]];
}
//-----------交换地图
function scal(totalTileArray:Array) {
	delete _root.tempMC.onEnterFrame;
	var tempArrayLength = totalTileArray.length;
	score += 10*Math.floor(tempArrayLength/6);
	var tempArray:Array = [];
	_root.tempMC.onEnterFrame = function() {
		for (var i = 0; i<tempArrayLength; i += 2) {
			_root["myTile"+totalTileArray[i]+"_"+totalTileArray[(i+1)]]._xscale -= 10;
			_root["myTile"+totalTileArray[i]+"_"+totalTileArray[(i+1)]]._yscale -= 10;
			if (_root["myTile"+totalTileArray[i]+"_"+totalTileArray[(i+1)]]._xscale<=0) {
				_root["myTile"+totalTileArray[i]+"_"+totalTileArray[(i+1)]]._xscale = 0;
				_root["myTile"+totalTileArray[i]+"_"+totalTileArray[(i+1)]]._yscale = 0;
			}
			if (_root["myTile"+totalTileArray[tempArrayLength-2]+"_"+totalTileArray[(tempArrayLength-1)]]._xscale<=0) {
				delete _root.tempMC.onEnterFrame;
				countSelUpTile();
				for (var i = 0; i<tempArrayLength; i += 2) {
					_root["myTile"+totalTileArray[i]+"_"+totalTileArray[(i+1)]]._xscale = 100;
					_root["myTile"+totalTileArray[i]+"_"+totalTileArray[(i+1)]]._yscale = 100;
				}
			}
		}
	};
}
//----------方块缩放
function countSelUpTile() {
	orderNum = 0;
	for (var i = 0; i<wNum; i++) {
		var k = 0;
		for (var j = 0; j<hNum; j++) {
			if (_root["myTile"+j+"_"+i]._yscale<=0) {
				k++;
				//有几个消除
				trace(_root["myTile"+j+"_"+i]);
				myMap[j][i] = "T";
				var tempNum = j+1;
				//tempNum为最大下标
			}
		}
		tempNum != undefined && k != 0 ? moveDownArray(tempNum, i) : null;
		for (var l = 0; l<tempNum; l++) {
			_root["myTile"+l+"_"+i]._y -= 30*k;
			if (_root["myTile"+l+"_"+i]._y != tileH*(l+1)) {
				trace(_root["myTile"+l+"_"+i]);
				moveDownTile(l, i);
			}
		}
	}
}
//-------提升要消除的方块的位置
function moveDownTile(b, c, d) {
	var a:MovieClip = _root["myTile"+b+"_"+c];
	var time:Number = 20;
	var begin = a._y;
	var end = tileH*(b+1);
	tileTween = new mx.transitions.Tween(a, "_y", moveToSize, begin, end, time);
	if (orderNum == 0) {
		orderNum++;
		tileTween.onMotionFinished = function() {
			totalClearTileArray = [];
			chick = true;
			allCheck();
		};
	}
}
//-------下落方块
function moveDownArray(a, b) {
	for (var i = a-1; i>=0; i--) {
		if (myMap[i-1][b] != undefined && myMap[i-1][b] != "T") {
			myMap[i][b] = myMap[i-1][b];
			myMap[i-1][b] = "T";
		} else if (myMap[i-1][b] == "T") {
			var kk:Number = i;
			while (kk>=0) {
				trace(myMap[kk-1][b]);
				if (myMap[kk-1][b] == undefined) {
					myMap[i][b] = random(selNum)+1;
					break;
				} else if (myMap[kk-1][b] != "T") {
					myMap[i][b] = myMap[kk-1][b];
					myMap[kk-1][b] = "T";
					break;
				}
				kk--;
			}
		} else {
			myMap[i][b] = random(selNum)+1;
		}
		_root["myTile"+i+"_"+b].gotoAndStop(myMap[i][b]);
	}
}
//--------------向下移动数组
function allCheck() {
	trace("*****全部重新检测******");
	for (var i = 0; i<8; i++) {
		checkMap(true, i);
		checkMap(false, i);
	}
	totalClearTileArray.length != 0 ? (chick=false, scal(totalClearTileArray)) : (chick=true, null);
}
//-----------------重新检测
function showArray() {
	for (var i = 0; i<8; i++) {
		trace(myMap[i]);
	}
}