/**
* Exception.as - Exception-handling class
* 
* Copyright (c) 2003, 2112 F/X.  All Rights Reserved.
*
* @ignore
*
* @author Jim Armstrong
* @version 1.0
*/

class Exception extends Error
{
  static var FATAL:Number   = -101;
  static var WARNING:Number = 0;

  private var __errorLevel:Number;    // error level - 0: warning, negative: fatal error
  private var __className:String;     // class in which this error occured
  private var __methodName:String;    // method in which this error occured
  private var __errorMessage:String;  // description of error

  public function get errorLevel()   { return __errorLevel   }
  public function get className()    { return __className    }
  public function get methodName()   { return __methodName   } 
  public function get errorMessage() { return __errorMessage }
  
  public function set errorLevel( _errLevel:Number ):Void
  {
    if ( _errLevel > 0 )
      _errLevel = 0;

    if ( _errLevel == 0 )
      __errorLevel = WARNING;
    else
      __errorLevel = FATAL;
  }

  public function set className( _cName:String ):Void
  {
    if ( _cName != undefined && _cName != "" && _cName != " " )
      __className = _cName;
  }

  public function set methodName( _mName:String ):Void
  {
    if ( _mName != undefined && _mName != "" && _mName != " " )
      __methodName = _mName;
  }

  public function set errorMessage( _mString:String ):Void
  {
    if ( _mString != undefined && _mString != "" && _mString != " " )
      __errorMessage = _mString;
  }

  public function Exception()
  {
    __errorLevel   = 0;
    __className    = "myClass";
    __methodName   = "myMethod()";
    __errorMessage = "Invalid argument or parameter setting.";
  }

}