import mx.collections.ArrayCollection;
import mx.rpc.http.HTTPService;
import flash.util.trace;
import flash.net.*;
import flash.events.*;
import mx.controls.Alert;
import mx.rpc.events.ResultEvent;

//MAIN DATA SOURCE
public var rawXML:XML;

//Reference directly to a more useful node.
[Bindable]
public var configData:XML;

//Referene directly to the selected news Item.
[Bindable]
public var newsItemData:XML;

//A lot of this code may be not be needed when the next version of Flex is released.  There has been "some" consideration of 
//adding direct binding to XML for components.  
//http://www.macromedia.com/cfusion/webforums/forum/messageview.cfm?catid=584&threadid=1084337&enterthread=y

              
private function start() {
	//This is called from the creationComplete from the MX:Application
	trace("Start");
	
	
	//Creates a URL loader, configures the listerns and loads our config.xml.
	var loader:URLLoader=new URLLoader();
	configureListeners(loader);
	  	
	var request:URLRequest= new URLRequest("config.xml")
	loader.load(request);
	
	
		
}



private function addNewsItem() {
	//Createa a new default ITEM node and adds it to the newsItem node.  We then rebuild the news Item Selector.
	
	//This is such a great way to work with XML in code!	
	var newItem:XML =
	<item>
		<title>Default Headline</title>
		<text>Default Body Text</text>
		<link>www.evilfree.com</link>
	</item>;
	
	
	//Add to news Item Node XML
	configData.news.appendChild(newItem);
    rebuildNewsSelector()	
}

private function removeNewsItem() {
	//This deletes the selected Item.
	
	//Make sure not all the items are deleted.  The Ticker needs at least one.
	if(configData.news.item.length()==1) {
		Alert.show("ERROR!  A news ticker without any stories is like a cloud without rain.  Nobody wants it...");
		return;
	}
	
	//Delete the currently selected Node
	var si:int=newsItemSelector.selectedIndex
	delete configData.news.item[si];
	
	rebuildNewsSelector();
	
	//now we pull the selection again, as the componenet will automatically update the index and accoutn for special situations like deleting the first item.
	si=newsItemSelector.selectedIndex
	trace(si);
	newsItemData=configData.news[0].item[si];
}

private function rebuildNewsSelector() {
	newsItemSelector.dataProvider=buildArray(configData.news.item.title);
}



private function buildArray(xmlList:XMLList):Array {
	//takes and XML list and creates an array from it.  The XML list must contain XML with only value per node... or this probably won't do what you want.
	//I also created an itemNum index when building the Array...
	var a:Array=[]
	var numItems:int=xmlList.length();
	for(var i:int=0;i<numItems;i++) {
		a.push({label:xmlList[i].toString(),itemNum:i+1});	
	}
	return a;
}


private function onComplete(event:Event):Void {
 		trace("XML LOADED");
		//var loader:URLLoader = URLLoader(event.target);
		rawXML=new XML(event.target.data);
		//To make future references a litle shorter we take the "config" node and make a seperate XML variable for it.
		//Without the [0] we would have an XML List containing the node, this way we get a regular XML variable.
		configData=rawXML.config[0]; 
		newsItemData=configData.news[0].item[0];
		
		//this is to work around a weird scaling bug when the source is included in the preview paramter.
		preview.source="ticker.swf";
}


private function httpResult(event:mx.rpc.events.ResultEvent):Void {
        var result:Object = event.result;
        // Alert.show("Upload Complete:"+event.result);  //the event.result is nice... lets you get info back from your PHP script.
         preview.source="ticker.swf";
         preview.width=Number(configData.@width);
         preview.height=Number(configData.@height);
        //Do something with the result.
}

private function httpFault(event:mx.rpc.events.FaultEvent):Void {
        var faultstring:String = event.fault.faultstring;
        Alert.show("Upload Failed:"+faultstring);
}




public function saveConfigData():Void {
	
	//set the preview to loading.  This also allows the SWF to reload when we set the source back to ticker after the save is completed.
	preview.source="loading.jpg";
	
	//Alert.show("XML:"+rawXML.toString());
	   var parameters:Object={data:rawXML.toString()}
        var service:HTTPService = new HTTPService();
        service.url = "saveConfig.php";
        service.method = "POST";
     //   trace("sending data to server");
        service.addEventListener("result", httpResult);
        service.addEventListener("fault", httpFault);
       service.send(parameters);
}



//This was all copied from the docs.
private function configureListeners(dispatcher:IEventDispatcher):Void {
			dispatcher.addEventListener(EventType.COMPLETE, onComplete);  //The event that really matters.
			dispatcher.addEventListener(EventType.OPEN, onOpen);
			dispatcher.addEventListener(ProgressEventType.PROGRESS, onProgress);
			dispatcher.addEventListener(SecurityErrorEventType.SECURITY_ERROR, onSecurityError);
			dispatcher.addEventListener(HTTPStatusEventType.HTTP_STATUS, onHTTPStatus);
			dispatcher.addEventListener(IOErrorEventType.IO_ERROR, onIOError);
}

private function onHTTPStatus(event:HTTPStatusEvent):Void {
	trace("onHTTPStatus: " + event);
}

private function onIOError(event:IOErrorEvent):Void {
	trace("onIOError: " + event);
}

private function onOpen(event:Event):Void {
	trace("onOpen: " + event);
}

private function onProgress(event:ProgressEvent):Void {
	trace("onProgress loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
}

private function onSecurityError(event:SecurityErrorEvent):Void {
	trace("onSecurityError: " + event);
}